<info>
ESM Csound Library
orc: samp   sco: samp3
Mono output.
 A violin line is folowed by a gong with fade-in & fade-out
 Amplitude envelopes of the input soundfiles are altered {p14-p16}
Allan Schindler  1/97
</info>
<tk_interface>


</tk_interface>
<mono>
    
; p5  = amplitude (0 -1 ) integer 0 -127 = midi veloc or 1000 - 32000 raw value
; p4 = pitch :  0 - 13. = pch  |  14 - 127 = midi note | negative = herz
; p6 = detuning
; p7 = input gen1 function # { if f99 & f98 not used}
; p8 = input pitch  { if f99 & f98 not used}

instr 1

idur = p3
ibasepitch init 0
p12 = (p12 = 0 ? 2 : p12 ) ; dummy end loop point for loscil
                           ; csound aborts without an end loop value, even
                           ; if no looping is specified
;========get pitch & midi note number
if p4 > 13.0 igoto midinote
if p4  < 0  igoto herz
     ; p4 is in pch
     icps = cpspch(p4)
        ; convert pch to midi note number
        imnum =  int((p4) - 3) * 12
        imnum =  imnum + (frac(p4) * 100)
;            ioct = octcps(icps) ; DELETE -- NOT NEEDED HERE
     igoto gotnote
midinote: 
     ; p4 gives midi note number
     imnum = p4
        ; convert midi note num to cps
        ioct = (p4/12) + 3.  ; returns oct decimal
        icps  =  cpsoct(ioct)
     igoto gotnote
herz: ; p4 is negative, so it is in herz
     icps = abs(p4)
     ioct = octcps(icps) 
     ipch = pchoct(ioct) 
        ; convert pch to midi note number
     imnum =  int((ipch) - 3) * 12
     imnum =  imnum + (frac(ipch) * 100)
gotnote:

; ------------------------------------------
; get gen01 audio function number & base pitch of soundfile
if p7 = 0 igoto tables
    ifno = p7      ; input soundfile function number
   ; if gen1 func specified in p7, p8 = input pitch : pch, MIDI note or herz
     if p8 > 13.0 igoto inmidinote
     if p8  < 0  igoto inherz
          ; p8 is in pch
          ibasepitch = cpspch(p8)
          igoto gotinpitch
     inmidinote: if p8 < 0  igoto inherz
          ; p8 gives midi note number : convert this to cps
             inoct = (p8/12) + 3.  ; returns oct decimal
             ibasepitch  =  cpsoct(inoct)
          igoto gotinpitch
     inherz: ; p8 is negative, so it is in herz
          ibasepitch = abs(p8)
          igoto gotinpitch

tables:  ; use func tables 99 & 98 to get source soundfile
ifno	table	imnum, 99	;keyboard mapping to gen1 ftables 
ibasno	table	ifno, 98        ; returns midi notes of the sonudfile samples
ibasoct	=	ibasno/12. + 3.
ibasepitch = cpsoct(ibasoct)
gotinpitch:
; ------------------------------------------
        ;  --- Detuning  module (mostly for use with "chorus" ) ---
   idetunepf = p6
if idetunepf = 0 goto gotdetune ;skip all this if detuning set to 0 in score
       idtcount init 0  ; counter
       idtmult =  (idetunepf > 0 ? 1.05946 : .94387) ;1/2 step freqency ratios
   idetune init 1.  ; detuning multiplier for p4 pitch
        icheck = abs(idetunepf)
        icheck = int(icheck)

  dumbloop:
	      idtcount = idtcount + 1   ; increment counter
	      idtmult = (icheck = 0 ? 1 : idtmult)
   idetune = idetune * idtmult 
   if idtcount < icheck igoto dumbloop
 ; microtonal detuning:
	idtmult = abs(idetunepf)
	idtmult = frac(idtmult)
	idtmult = idtmult * .05496
	idtmult = (idetunepf > 0 ? idtmult : - idtmult)
   idetune = idetune + idtmult
icps = icps * idetune 
gotdetune:   ; ---end of detuning module -------
; -----------------------------------------------------------
; optional TURN OFF INSTRUMENT when p9 time reached {only a portion of the
; input soundfile, specified in p9,  is used}
if p9 = 0 goto playon
        istoptime = p9   ; 
;	inotedur = ( p3 < istoptime ? p3 : istoptime)
;	inoteoff = inotedur + p2
        itransp = ibasepitch/icps
	istoptime = istoptime * itransp 
	istoptime = istoptime - .005
	inotedur = ( p3 < istoptime ? p3 : istoptime)
        idur = inotedur
	inoteoff = inotedur + p2

        print p2, p4, inotedur, inoteoff  ; print note start time, dur & end time for user
	timout istoptime , p3 , shutdown
	goto playon
		shutdown: 
		turnoff
		kgoto output
playon:
 ; ==============================================================
; insert for lpcpitch, xsynpitch, gxsynpitch:
kpitch init icps
 ; ==============================================================
       ; Determine "peak" amplitude:
	iamp init 0
	iamp = (p5  < 10.1 ? p5  : iamp) ; p5  = multiplier for original soundfile amp.
	iamp = (p5  > 10.1 ? p5/32767 : iamp) ; p5  gives new raw amplitude
	iamp = (iamp = 0 ? 1. : iamp)
a1	loscil	iamp, icps , ifno, ibasepitch , p10, p11, p12
 ; ==============================================================
; FADE OUT and OPTIONAL NEW AMPLITUDE ENVELOPE
	irise = (p14 = 0? .0001 : p14)
	irise = (p14 < 100 ? irise : (p14 - 100)  * idur)
	irise = (p14 < 0 ? abs(p14)  * idur : irise)
	iatss = (p16 = 0  ? 1 : p16)
	idec = (p15 = 0? .0001 : p15)
	idec = (p15 < 100 ? idec : (p15 - 100)  * idur)
	idec = (p15 < 0 ? abs(p15)  * idur : idec)

        idec = (idec > .04 ? idec : .04) ; default decay of .04 to avoid clicks
                               ; if p3 is less than duration of input soundfile
	amp expseg .005, irise, 1., idur - (irise + idec), iatss , idec, .005
        a1 = a1 * amp
; ------------------------------------------
; OPTIONAL BRIGHTNESS -- use with new envelope for cresc & dim.
bright:  ibrightest = p17 + p18
if ibrightest = 0 goto output
kbright init p17
if p18 = 0 goto brightscale
   ip19 = (p19 > 100 ? ((p19 - 100) * idur) - .1 : p19)
   ip19 = (p19 < 0 ? (abs(p19) * idur) - .1 : p19)
   ip19 = (ip19 = 0 ? (.9*idur) - idec : ip19)

   ip20 init icps
if p20 = 0 igoto gotcf
   ip20 = (p20 < 13.1 ? cpspch(p20) : p20 )
gotcf:
   kbright expseg p17, .1,p17,ip19, p18, idur, p18
brightscale:
      ihp = icps*1.5
        iscale = octcps(ihp)
        iscale = (18.25 - iscale) * .1
        iscale = (iscale < 1. ? iscale : iscale * iscale )
      ihp = ihp * iscale
   ahi atone .9*a1, ihp
   alo tone  .9*a1, ihp
   a1 balance (kbright*ahi) + ((2. - kbright)* alo), a1
 ; --------------------------------------------------------
output:
;Standard out statement
out a1
endin
</mono>
<stereo>

</stereo>
<quad>


</quad>
<score>
f20 0 0 -1 "/sflib/perc/gong.bf2" 0 0 0 
f1 0 0 -1 "/sflib/string/vln.g3" 0 0 0
f2 0 0 -1 "/sflib/string/vln.b3" 0 0 0
f3 0 0 -1 "/sflib/string/vln.ds4" 0 0 0
f4 0 0 -1 "/sflib/string/vln.g4" 0 0 0
f5 0 0 -1 "/sflib/string/vln.b4" 0 0 0
f6 0 0 -1 "/sflib/string/vln.ds5" 0 0 0
f7 0 0 -1 "/sflib/string/vln.g5" 0 0 0
f8 0 0 -1 "/sflib/string/vln.b5" 0 0 0
f9 0 0 -1 "/sflib/string/vln.ds6" 0 0 0
f10 0 0 -1 "/sflib/string/vln.g6" 0 0 0
f11 0 0 -1 "/sflib/string/vln.c7" 0 0 0
f99 0 128 -17 0 1 57 2 61 3 65 4 69 5 73 6 77 7 81 8 85 9 89 10 93 11
f98 0 16 -2 0 55 59 63 67 71 75 79 83 87 91 96 
f100 0 1024 10 1.
f50 0 65 7 0 64 1.
f52 0 65 7 0 32 1. 32 0
f60 0 65 5 .01 64 1.
f62 0 65 5 .01 32 1. 32 .01
f57 0 64 7 0 31 0 1 1. 31 1. 1 0 
f58 0 64 7 0 21 0 1 1. 20 1. 1 -1 20 -1 1 0 
  i1 0.000 0.267 7.03 15016 0 0 6.10 0 0 0 0 0 0 -0.230 0.879 0.938 0 0 0
  i1 0.229 0.245 8.09 15405 0 0 6.10 0 0 0 0 0 0 -0.240 0.710 0.983 0 0 0
 ci1 0.444 0.244 8.09 16304 0 0 6.10 0 0 0 0 0 0 -0.206 0.707 1.040 0 0 0 <rest>
  i1 0.654 0.236 7.08 18383 0 0 6.10 0 0 0 0 0 0 -0.254 0.996 1.141 0 0 0
  i1 0.879 0.188 8.02 19117 0 0 6.10 0 0 0 0 0 0 -0.235 0.780 1.256 0 0 0
  i1 1.040 0.183 8.07 20331 0 0 6.10 0 0 0 0 0 0 -0.233 0.942 1.290 0 0 0
  i1 1.213 0.180 9.06 23792 0 0 6.10 0 0 0 0 0 0 -0.235 0.922 1.422 0 0 0
  i1 1.383 0.181 9.00 21962 0 0 6.10 0 0 0 0 0 0 -0.207 0.911 1.480 0 0 0
  i1 1.540 0.174 9.11 22679 0 0 6.10 0 0 0 0 0 0 -0.203 1.135 1.486 0 0 0
  i1 1.697 0.315 9.05 25030 0 0 6.10 0 0 0 0 0 0 -0.220 1.137 1.620 0 0 0
  i1 1.954 0.360 10.04 27453 0 0 6.10 0 0 0 0 0 0 -0.204 1.056 1.754 0 0 0
 ci1 2.273 0.192 10.04 12000 0 0 6.10 0 0 0 0 0 0 -0.200 1.156 1.886 0 0 0 <rest>
  i1 2.451 3.600 10.11 12000 0 0 6.10 0 0 0 0 0 0 -0.300 0.060 0.800 0 -0.100 0
  i1 3.614 5.000 6.04 7000 0 20 6.10 0 0 0 0 0 0.700 -0.300 0.300 0.800 0.050 -0.200 0
e
</score>

