<info>
i is ex6-4-2
ECMC Csound Tutorial example ex6-4-2
</info>
<tk_interface>
</tk_interface>
<mono>
;  #############################################################
;  orchestra file examples ex6-4-1, 6-4-2 and 6-4-3
; non-12 tone tuning examples
;  #############################################################

sr=44100
kr=2205
ksmps=20
nchnls=1


instr 1

icps  cps2pch  p4, p6
        ; convert pch to midi note number
        imidinote =  int((p4) - 3) * 12
        imidinote = int(imidinote + ((frac(p4) * (12/p6)) * 100))
; ------------------------------------------

  ; use function tables 99 & 98 to get closest multisample soundfile
ifno	table	imidinote, 99  ;keyboard mapping to gen1 function tables 
ibasno	table	ifno, 98        ; returns midi notes of the sonudfile samples
ibasoct	=	ibasno/12. + 3.
ibasepitch = cpsoct(ibasoct)
; ------------------------------------------
iendloop = 1 ; dummy end loop point for loscil
                       ; csound aborts without an end loop value, even
                       ; if no looping is specified

asig	loscil	1, icps , ifno, ibasepitch , 0, 0, iendloop
print icps, imidinote, ifno, ibasepitch
; ------------------------------------------
; AMPLITUDE SCALING and OPTIONAL NEW AMPLITUDE ENVELOPE
	iamp = p5
	irise = (p7 = 0? .0001 : p7)
	idec = (p8 = 0? .0001 : p8)
kamp expseg .005, irise, iamp, p3 - (irise + idec), iamp , idec, .005
asig = asig * kamp
; ------------------------------------------
out asig
endin
</mono>
<stereo>
</stereo>
<score>

                  SCORE-11, Version 1.4
Copyright (C) 1982, 1990, 1992, 1995 by Alexander R. Brinkman
     Eastman School of Music, University of Rochester

f1 0 0 -1 "/sflib/wind/fl.c4" 0 0 0
f2 0 0 -1 "/sflib/wind/fl.e4" 0 0 0
f3 0 0 -1 "/sflib/wind/fl.gs4" 0 0 0
f4 0 0 -1 "/sflib/wind/fl.c5" 0 0 0
f5 0 0 -1 "/sflib/wind/fl.e5" 0 0 0
f6 0 0 -1 "/sflib/wind/fl.gs5" 0 0 0
f7 0 0 -1 "/sflib/wind/fl.c6" 0 0 0
f8 0 0 -1 "/sflib/wind/fl.e6" 0 0 0
f9 0 0 -1 "/sflib/wind/fl.gs6" 0 0 0
f10 0 0 -1 "/sflib/wind/fl.c7" 0 0 0
f99 0 128 -17 0 1 62 2 66 3 70 4 74 5 78 6 82 7 86 8 90 9 94 10
f98 0 16 -2 0 60 64 68 72 76 80 84 88 92 99
  i1 0.000 0.600 8.000 0.500 13 0 0.178
  i1 0.500 0.600 8.010 0.500 13 0 0.191
  i1 1.000 0.600 8.020 0.500 13 0 0.183
  i1 1.500 0.600 8.030 0.500 13 0 0.195
  i1 2.000 0.600 8.040 0.500 13 0 0.162
  i1 2.500 0.600 8.050 0.500 13 0 0.194
  i1 3.000 0.600 8.060 0.500 13 0 0.184
  i1 3.500 0.600 8.070 0.500 13 0 0.187
  i1 4.000 0.600 8.080 0.500 13 0 0.168
  i1 4.500 0.600 8.090 0.500 13 0 0.181
  i1 5.000 0.600 8.100 0.500 13 0 0.178
  i1 5.500 0.600 8.110 0.500 13 0 0.155
  i1 6.000 0.600 8.120 0.500 13 0 0.172
  i1 6.750 0.600 8.130 0.500 13 0 0.183
  i1 6.757 0.600 8.000 0.500 13 0 0.186
e
</score>
